-
Notifications
You must be signed in to change notification settings - Fork 1
/
TLCS900H_single.s
764 lines (743 loc) · 26.7 KB
/
TLCS900H_single.s
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
//
// TLCS900H_single.s
// TLCS900H
//
// Created by Fredrik Ahlström on 2008-04-02.
// Copyright © 2008-2024 Fredrik Ahlström. All rights reserved.
//
#ifdef __arm__
#include "TLCS900H_mac.h"
.global sngNOP
.global sngNORMAL
.global sngMAX
.global sngHALT
.global sngLD8_8
.global sngLD8_16
.global sngRCF
.global sngSCF
.global sngCCF
.global sngZCF
.global sngJP16
.global sngJP24
.global sngPUSH8
.global sngPUSH16
.global sngPUSHA
.global sngPUSHF
.global sngPUSHSR
.global sngPOPA
.global sngPOPF
.global sngPOPSR
.global sngRET
.global sngRETD
.global sngRETI
.global sngINCF
.global sngDECF
.global sngLDF
.global sngEI
.global sngEX
.global sngCALL16
.global sngCALL24
.global sngCALR
.global sngLDiRW
.global sngLDiRA
.global sngLDiRB
.global sngLDiRC
.global sngLDiRD
.global sngLDiRE
.global sngLDiRH
.global sngLDiRL
.global sngLDW
.global sngLDL
.global sngPUSHW
.global sngPUSHL
.global sngPOPW
.global sngPOPL
.global sngJR_never
.global sngJR_lt
.global sngJR_le
.global sngJR_ule
.global sngJR_ov
.global sngJR_mi
.global sngJR_z
.global sngJR_c
.global sngJR
.global sngJR_ge
.global sngJR_gt
.global sngJR_ugt
.global sngJR_nov
.global sngJR_pl
.global sngJR_nz
.global sngJR_nc
.global sngJRL_never
.global sngJRL_lt
.global sngJRL_le
.global sngJRL_ule
.global sngJRL_ov
.global sngJRL_mi
.global sngJRL_z
.global sngJRL_c
.global sngJRL
.global sngJRL_ge
.global sngJRL_gt
.global sngJRL_ugt
.global sngJRL_nov
.global sngJRL_pl
.global sngJRL_nz
.global sngJRL_nc
.global sngLDX
.global sngSWI
.global sngSWI2
.syntax unified
.arm
;@----------------------------------------------------------------------------
#ifdef GBA
.section .iwram, "ax", %progbits ;@ For the GBA
#else
.section .text ;@ For everything else
#endif
.align 2
;@----------------------------------------------------------------------------
;@----------------------------------------------------------------------------
sngNOP: ;@ 0x00, No Operation
;@----------------------------------------------------------------------------
t9fetch 2
;@----------------------------------------------------------------------------
sngNORMAL: ;@ 0x01, flag thing not on TLSC-900H
;@----------------------------------------------------------------------------
;@----------------------------------------------------------------------------
sngMAX: ;@ 0x04, flag thing not on TLSC-900H
;@----------------------------------------------------------------------------
t9fetch 4
;@----------------------------------------------------------------------------
sngPUSHSR: ;@ 0x02 Push Status Register
;@----------------------------------------------------------------------------
bl pushSR
t9fetch 4
;@----------------------------------------------------------------------------
sngPOPSR: ;@ 0x03 Pop Status Register
;@----------------------------------------------------------------------------
bl pop16
bl setStatusReg
bl checkInterrupt
t9fetch 6
;@----------------------------------------------------------------------------
sngHALT: ;@ 0x05, Halt CPU
;@----------------------------------------------------------------------------
sub t9pc,t9pc,#1
movs r0,t9cycles,asr#T9CYC_SHIFT+2 ;@
bicpl t9cycles,t9cycles,r0,lsl#T9CYC_SHIFT+2 ;@ Consume all cycles in steps of 4.
ldrb r0,[t9ptr,#tlcsWdMode]
and r0,r0,#0x0C ;@ Halt Mode
strb r0,[t9ptr,#tlcsHaltMode]
t9fetch 8
;@----------------------------------------------------------------------------
sngEI: ;@ 0x06 Enable Interrupt
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
bl setStatusIFF
bl checkInterrupt
t9fetch 5
;@----------------------------------------------------------------------------
sngRETI: ;@ 0x07 Return from Interrupt
;@----------------------------------------------------------------------------
bl pop16
bl setStatusReg
bl pop32
bl encode_r0_pc
bl checkInterrupt
t9fetch 12
;@----------------------------------------------------------------------------
sngLD8_8: ;@ 0x08, Store immediate byte in low memory.
;@----------------------------------------------------------------------------
ldrb t9Mem,[t9pc],#1
ldrb r0,[t9pc],#1
bl t9StoreB_Low
t9fetch 5
;@----------------------------------------------------------------------------
sngPUSH8: ;@ 0x09 Push immediate byte
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
bl push8
t9fetch 4
;@----------------------------------------------------------------------------
sngLD8_16: ;@ 0x0A, Store immediate word in low memory.
;@----------------------------------------------------------------------------
ldrb t9Mem,[t9pc],#1
ldrb r0,[t9pc],#1
ldrb r2,[t9pc],#1
orr r0,r0,r2,lsl#8
bl t9StoreW_mem
t9fetch 6
;@----------------------------------------------------------------------------
sngPUSH16: ;@ 0x0B Push immediate word
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
ldrb r1,[t9pc],#1
orr r0,r0,r1,lsl#8
bl push16
t9fetch 5
;@----------------------------------------------------------------------------
sngINCF: ;@ 0x0C Increment Register File Pointer
;@----------------------------------------------------------------------------
ldrb r0,[t9ptr,#tlcsSrB]
add r0,r0,#1
bl setStatusRFP
t9fetch 2
;@----------------------------------------------------------------------------
sngDECF: ;@ 0x0D Decrement Register File Pointer
;@----------------------------------------------------------------------------
ldrb r0,[t9ptr,#tlcsSrB]
sub r0,r0,#1
bl setStatusRFP
t9fetch 2
;@----------------------------------------------------------------------------
sngRET: ;@ 0x0E Return
;@----------------------------------------------------------------------------
bl pop32
bl encode_r0_pc
t9fetch 9
;@----------------------------------------------------------------------------
sngRETD: ;@ 0x0F Return and Deallocate
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
ldrb r1,[t9pc],#1
orr t9pc,r0,r1,lsl#8 ;@ Use t9pc as temp register.
bl pop32
ldr r1,[t9gprBank,#RXSP]
add r1,r1,t9pc
str r1,[t9gprBank,#RXSP]
bl encode_r0_pc
t9fetch 9
;@----------------------------------------------------------------------------
sngRCF: ;@ 0x10, Reset Carry Flag
;@----------------------------------------------------------------------------
bic t9f,t9f,#PSR_H+PSR_C+PSR_n ;@ Clear CH and N (or V, manual not clear about it).
t9fetch 2
;@----------------------------------------------------------------------------
sngSCF: ;@ 0x11, Set Carry Flag
;@----------------------------------------------------------------------------
bic t9f,t9f,#PSR_H|PSR_n ;@ Clear HN
orr t9f,t9f,#PSR_C ;@ Set C
t9fetch 2
;@----------------------------------------------------------------------------
sngCCF: ;@ 0x12, Complement Carry Flag
;@----------------------------------------------------------------------------
bic t9f,t9f,#PSR_n ;@ Clear N, actually H is unknown as well (old C?).
eor t9f,t9f,#PSR_C ;@ Invert C
t9fetch 2
;@----------------------------------------------------------------------------
sngZCF: ;@ 0x13, Zero to Carry Flag
;@----------------------------------------------------------------------------
bic t9f,t9f,#PSR_n|PSR_C ;@ Clear N, actually H is unknown as well (old C?).
tst t9f,#PSR_Z ;@ Z
orreq t9f,t9f,#PSR_C ;@ Inverted Z to C
t9fetch 2
;@----------------------------------------------------------------------------
sngPUSHA: ;@ 0x14 Push register A
;@----------------------------------------------------------------------------
ldrb r0,[t9gprBank,#RegA]
bl push8
t9fetch 3
;@----------------------------------------------------------------------------
sngPOPA: ;@ 0x15 Pop register A
;@----------------------------------------------------------------------------
bl pop8
strb r0,[t9gprBank,#RegA]
t9fetch 4
;@----------------------------------------------------------------------------
sngEX: ;@ 0x16 Exchange F & F'
;@----------------------------------------------------------------------------
mov r0,t9f
ldrb t9f,[t9ptr,#tlcsFDash]
strb r0,[t9ptr,#tlcsFDash]
t9fetch 2
;@----------------------------------------------------------------------------
sngLDF: ;@ 0x17 Load Register File Pointer
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
bl setStatusRFP
t9fetch 2
;@----------------------------------------------------------------------------
sngPUSHF: ;@ 0x18 Push Flag register
;@----------------------------------------------------------------------------
and r0,t9f,#PSR_H
and r1,t9f,#PSR_S|PSR_Z
orr r0,r0,r1,lsl#4
movs r1,t9f,lsl#31
orrmi r0,r0,#VF
and r1,t9f,#PSR_n
adc r0,r0,r1,lsr#6 ;@ NF & CF
bl push8
t9fetch 3
;@----------------------------------------------------------------------------
sngPOPF: ;@ 0x19 Pop Flag register
;@----------------------------------------------------------------------------
bl pop8
and t9f,r0,#HF
tst r0,#CF
orrne t9f,t9f,#PSR_C
and r1,r0,#SF|ZF
movs r0,r0,lsl#30
adc t9f,t9f,r1,lsr#4 ;@ Also sets V/P Flag.
orrmi t9f,t9f,#PSR_n
t9fetch 4
;@----------------------------------------------------------------------------
sngJP16: ;@ 0x1A, Jump to 16bit address
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
ldrb r1,[t9pc],#1
orr t9pc,r0,r1,lsl#8
bl reencode_pc
t9fetch 7
;@----------------------------------------------------------------------------
sngJP24: ;@ 0x1B, Jump to 24bit address
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
ldrb r1,[t9pc],#1
ldrb r2,[t9pc],#1
orr r0,r0,r1,lsl#8
orr t9pc,r0,r2,lsl#16
bl reencode_pc
t9fetch 7
;@----------------------------------------------------------------------------
sngCALL16: ;@ 0x1C Call 16bit address
;@----------------------------------------------------------------------------
ldr r0,[t9ptr,#tlcsLastBank]
ldrb r1,[t9pc],#1
ldrb r2,[t9pc],#1
sub r0,t9pc,r0
orr t9pc,r1,r2,lsl#8 ;@ New pc
bl push32 ;@ Push old pc
bl reencode_pc
t9fetch 12
;@----------------------------------------------------------------------------
sngCALL24: ;@ 0x1D Call 24bit address
;@----------------------------------------------------------------------------
ldr r0,[t9ptr,#tlcsLastBank]
ldrb r1,[t9pc],#1
ldrb r2,[t9pc],#1
ldrb r3,[t9pc],#1
sub r0,t9pc,r0
orr r1,r1,r2,lsl#8
orr t9pc,r1,r3,lsl#16 ;@ New pc
bl push32 ;@ Push old pc
bl reencode_pc
t9fetch 12
;@----------------------------------------------------------------------------
sngCALR: ;@ 0x1E Call Relative PC+d16
;@----------------------------------------------------------------------------
ldr r0,[t9ptr,#tlcsLastBank]
ldrb r1,[t9pc],#1
ldrsb r2,[t9pc],#1
orr r2,r1,r2,lsl#8 ;@ Offset
sub r0,t9pc,r0 ;@ New pc
add t9pc,t9pc,r2
bl push32 ;@ Push old pc
t9fetch 12
;@----------------------------------------------------------------------------
sngLDiRW: ;@ 0x20 Load immediate byte to W
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
strb r0,[t9gprBank,#RegW]
t9fetch 2
;@----------------------------------------------------------------------------
sngLDiRA: ;@ 0x21 Load immediate byte to A
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
strb r0,[t9gprBank,#RegA]
t9fetch 2
;@----------------------------------------------------------------------------
sngLDiRB: ;@ 0x22 Load immediate byte to B
sngLDiRC: ;@ 0x23 Load immediate byte to C
sngLDiRD: ;@ 0x24 Load immediate byte to D
sngLDiRE: ;@ 0x25 Load immediate byte to E
sngLDiRH: ;@ 0x26 Load immediate byte to H
sngLDiRL: ;@ 0x27 Load immediate byte to L
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
and t9Reg,t9opCode,#0x07
movs t9Reg,t9Reg,lsr#1
orrcc t9Reg,t9Reg,#0x40000000
strb r0,[t9gprBank,t9Reg,ror#30]
t9fetch 2
;@----------------------------------------------------------------------------
sngLDW: ;@ 0x30-0x37 Load immediate word to reg
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
ldrb r1,[t9pc],#1
and t9Reg,t9opCode,#0x07
mov t9Reg,t9Reg,lsl#2
orr r0,r0,r1,lsl#8
strh r0,[t9gprBank,t9Reg]
t9fetch 3
;@----------------------------------------------------------------------------
sngLDL: ;@ 0x40-0x47 Load immediate long to reg
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
ldrb r1,[t9pc],#1
ldrb r2,[t9pc],#1
ldrb r3,[t9pc],#1
and t9Reg,t9opCode,#0x07
orr r0,r0,r1,lsl#8
orr r0,r0,r2,lsl#16
orr r0,r0,r3,lsl#24
str r0,[t9gprBank,t9Reg,lsl#2]
t9fetch 5
;@----------------------------------------------------------------------------
sngPUSHW: ;@ 0x28-0x2F Push word
;@----------------------------------------------------------------------------
and t9Reg,t9opCode,#0x07
ldr r0,[t9gprBank,t9Reg,lsl#2]
bl push16
t9fetch 3
;@----------------------------------------------------------------------------
sngPUSHL: ;@ 0x38-0x3F Push long
;@----------------------------------------------------------------------------
and t9Reg,t9opCode,#0x07
ldr r0,[t9gprBank,t9Reg,lsl#2]
bl push32
t9fetch 5
;@----------------------------------------------------------------------------
sngPOPW: ;@ 0x48-0x4F Pop word
;@----------------------------------------------------------------------------
bl pop16
and t9Reg,t9opCode,#0x07
mov t9Reg,t9Reg,lsl#2
strh r0,[t9gprBank,t9Reg]
t9fetch 4
;@----------------------------------------------------------------------------
sngPOPL: ;@ 0x58-0x5F Pop long
;@----------------------------------------------------------------------------
bl pop32
and t9Reg,t9opCode,#0x07
str r0,[t9gprBank,t9Reg,lsl#2]
t9fetch 6
;@----------------------------------------------------------------------------
sngJR_never: ;@ 0x60, Jump Relative never
;@----------------------------------------------------------------------------
add t9pc,t9pc,#1
t9fetchr 4
;@----------------------------------------------------------------------------
sngJR_lt: ;@ 0x61, Jump Relative Less Than
;@----------------------------------------------------------------------------
ldrsb r0,[t9pc],#1
eor r1,t9f,t9f,lsr#3 ;@ S^V
tst r1,#PSR_V
addne t9pc,t9pc,r0
subne t9cycles,t9cycles,#4*T9CYCLE
t9fetch 4
;@----------------------------------------------------------------------------
sngJR_le: ;@ 0x62, Jump Relative Less or Equal
;@----------------------------------------------------------------------------
ldrsb r0,[t9pc],#1
mov r1,t9f,lsl#28
msr cpsr_flg,r1
addle t9pc,t9pc,r0
suble t9cycles,t9cycles,#4*T9CYCLE
t9fetch 4
;@----------------------------------------------------------------------------
sngJR_ule: ;@ 0x63, Jump Relative Unsigned Less or Equal
;@----------------------------------------------------------------------------
ldrsb r0,[t9pc],#1
orr r1,t9f,t9f,lsr#1 ;@ C|Z
tst r1,#PSR_C
addne t9pc,t9pc,r0
subne t9cycles,t9cycles,#4*T9CYCLE
t9fetch 4
;@----------------------------------------------------------------------------
sngJR_ov: ;@ 0x64, Jump Relative Overflow
;@----------------------------------------------------------------------------
ldrsb r0,[t9pc],#1
tst t9f,#PSR_V
addne t9pc,t9pc,r0
subne t9cycles,t9cycles,#4*T9CYCLE
t9fetch 4
;@----------------------------------------------------------------------------
sngJR_mi: ;@ 0x65, Jump Relative Minus
;@----------------------------------------------------------------------------
ldrsb r0,[t9pc],#1
tst t9f,#PSR_S
addne t9pc,t9pc,r0
subne t9cycles,t9cycles,#4*T9CYCLE
t9fetchr 4
;@----------------------------------------------------------------------------
sngJR_z: ;@ 0x66, Jump Relative Zero
;@----------------------------------------------------------------------------
ldrsb r0,[t9pc],#1
tst t9f,#PSR_Z
addne t9pc,t9pc,r0
subne t9cycles,t9cycles,#4*T9CYCLE
t9fetchr 4
;@----------------------------------------------------------------------------
sngJR_c: ;@ 0x67, Jump Relative Carry
;@----------------------------------------------------------------------------
ldrsb r0,[t9pc],#1
tst t9f,#PSR_C
addne t9pc,t9pc,r0
subne t9cycles,t9cycles,#4*T9CYCLE
t9fetch 4
;@----------------------------------------------------------------------------
sngJR: ;@ 0x68, Jump Relative
;@----------------------------------------------------------------------------
ldrsb r0,[t9pc],#1
add t9pc,t9pc,r0
t9fetchr 8
;@----------------------------------------------------------------------------
sngJR_ge: ;@ 0x69, Jump Relative Greater or Equal
;@----------------------------------------------------------------------------
ldrsb r0,[t9pc],#1
eor r1,t9f,t9f,lsr#3 ;@ S^V
tst r1,#PSR_V
addeq t9pc,t9pc,r0
subeq t9cycles,t9cycles,#4*T9CYCLE
t9fetch 4
;@----------------------------------------------------------------------------
sngJR_gt: ;@ 0x6A, Jump Relative Greater Than
;@----------------------------------------------------------------------------
ldrsb r0,[t9pc],#1
mov r1,t9f,lsl#28
msr cpsr_flg,r1
addgt t9pc,t9pc,r0
subgt t9cycles,t9cycles,#4*T9CYCLE
t9fetch 4
;@----------------------------------------------------------------------------
sngJR_ugt: ;@ 0x6B, Jump Relative Unsigned Greater Than
;@----------------------------------------------------------------------------
ldrsb r0,[t9pc],#1
orr r1,t9f,t9f,lsr#1 ;@ C|Z
tst r1,#PSR_C
addeq t9pc,t9pc,r0
subeq t9cycles,t9cycles,#4*T9CYCLE
t9fetch 4
;@----------------------------------------------------------------------------
sngJR_nov: ;@ 0x6C, Jump Relative Not Overflow
;@----------------------------------------------------------------------------
ldrsb r0,[t9pc],#1
tst t9f,#PSR_V
addeq t9pc,t9pc,r0
subeq t9cycles,t9cycles,#4*T9CYCLE
t9fetch 4
;@----------------------------------------------------------------------------
sngJR_pl: ;@ 0x6D, Jump Relative Plus
;@----------------------------------------------------------------------------
ldrsb r0,[t9pc],#1
tst t9f,#PSR_S
addeq t9pc,t9pc,r0
subeq t9cycles,t9cycles,#4*T9CYCLE
t9fetchr 4
;@----------------------------------------------------------------------------
sngJR_nz: ;@ 0x6E, Jump Relative Not Zero
;@----------------------------------------------------------------------------
ldrsb r0,[t9pc],#1
tst t9f,#PSR_Z
addeq t9pc,t9pc,r0
subeq t9cycles,t9cycles,#4*T9CYCLE
t9fetchr 4
;@----------------------------------------------------------------------------
sngJR_nc: ;@ 0x6F, Jump Relative Not Carry
;@----------------------------------------------------------------------------
ldrsb r0,[t9pc],#1
tst t9f,#PSR_C
addeq t9pc,t9pc,r0
subeq t9cycles,t9cycles,#4*T9CYCLE
t9fetch 4
;@----------------------------------------------------------------------------
sngJRL_never: ;@ 0x70 Jump Relative Long, Never
;@----------------------------------------------------------------------------
add t9pc,t9pc,#2
t9fetch 4
;@----------------------------------------------------------------------------
sngJRL_lt: ;@ 0x71 Jump Relative Long, Less Than
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
ldrsb r1,[t9pc],#1
orr r0,r0,r1,lsl#8
eor r1,t9f,t9f,lsr#3 ;@ S^V
tst r1,#PSR_V
addne t9pc,t9pc,r0
subne t9cycles,t9cycles,#4*T9CYCLE
t9fetch 4
;@----------------------------------------------------------------------------
sngJRL_le: ;@ 0x72 Jump Relative Long, Less or Equal
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
ldrsb r1,[t9pc],#1
orr r0,r0,r1,lsl#8
mov r1,t9f,lsl#28
msr cpsr_flg,r1
addle t9pc,t9pc,r0
suble t9cycles,t9cycles,#4*T9CYCLE
t9fetch 4
;@----------------------------------------------------------------------------
sngJRL_ule: ;@ 0x73 Jump Relative Long, Unsigned Less or Equal
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
ldrsb r1,[t9pc],#1
orr r0,r0,r1,lsl#8
orr r1,t9f,t9f,lsr#1 ;@ C|Z
tst r1,#PSR_C
addne t9pc,t9pc,r0
subne t9cycles,t9cycles,#4*T9CYCLE
t9fetch 4
;@----------------------------------------------------------------------------
sngJRL_ov: ;@ 0x74 Jump Relative Long, Overflow
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
ldrsb r1,[t9pc],#1
orr r0,r0,r1,lsl#8
tst t9f,#PSR_V
addne t9pc,t9pc,r0
subne t9cycles,t9cycles,#4*T9CYCLE
t9fetch 4
;@----------------------------------------------------------------------------
sngJRL_mi: ;@ 0x75 Jump Relative Long, Minus
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
ldrsb r1,[t9pc],#1
orr r0,r0,r1,lsl#8
tst t9f,#PSR_S
addne t9pc,t9pc,r0
subne t9cycles,t9cycles,#4*T9CYCLE
t9fetch 4
;@----------------------------------------------------------------------------
sngJRL_z: ;@ 0x76 Jump Relative Long, Zero
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
ldrsb r1,[t9pc],#1
orr r0,r0,r1,lsl#8
tst t9f,#PSR_Z
addne t9pc,t9pc,r0
subne t9cycles,t9cycles,#4*T9CYCLE
t9fetch 4
;@----------------------------------------------------------------------------
sngJRL_c: ;@ 0x77 Jump Relative Long, Carry
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
ldrsb r1,[t9pc],#1
orr r0,r0,r1,lsl#8
tst t9f,#PSR_C
addne t9pc,t9pc,r0
subne t9cycles,t9cycles,#4*T9CYCLE
t9fetch 4
;@----------------------------------------------------------------------------
sngJRL: ;@ 0x78 Jump Relative Long
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
ldrsb r1,[t9pc],#1
orr r0,r0,r1,lsl#8
add t9pc,t9pc,r0
t9fetch 8
;@----------------------------------------------------------------------------
sngJRL_ge: ;@ 0x79 Jump Relative Long, Greater or Equal
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
ldrsb r1,[t9pc],#1
orr r0,r0,r1,lsl#8
eor r1,t9f,t9f,lsr#3 ;@ S^V
tst r1,#PSR_V
addeq t9pc,t9pc,r0
subeq t9cycles,t9cycles,#4*T9CYCLE
t9fetch 4
;@----------------------------------------------------------------------------
sngJRL_gt: ;@ 0x7A Jump Relative Long, Greater Than
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
ldrsb r1,[t9pc],#1
orr r0,r0,r1,lsl#8
mov r1,t9f,lsl#28
msr cpsr_flg,r1
addgt t9pc,t9pc,r0
subgt t9cycles,t9cycles,#4*T9CYCLE
t9fetch 4
;@----------------------------------------------------------------------------
sngJRL_ugt: ;@ 0x7B Jump Relative Long, Unsigned Greater
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
ldrsb r1,[t9pc],#1
orr r0,r0,r1,lsl#8
orr r1,t9f,t9f,lsr#1 ;@ C|Z
tst r1,#PSR_C
addeq t9pc,t9pc,r0
subeq t9cycles,t9cycles,#4*T9CYCLE
t9fetch 4
;@----------------------------------------------------------------------------
sngJRL_nov: ;@ 0x7C Jump Relative Long, Not Overflow
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
ldrsb r1,[t9pc],#1
orr r0,r0,r1,lsl#8
tst t9f,#PSR_V
addeq t9pc,t9pc,r0
subeq t9cycles,t9cycles,#4*T9CYCLE
t9fetch 4
;@----------------------------------------------------------------------------
sngJRL_pl: ;@ 0x7D Jump Relative Long, Plus
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
ldrsb r1,[t9pc],#1
orr r0,r0,r1,lsl#8
tst t9f,#PSR_S
addeq t9pc,t9pc,r0
subeq t9cycles,t9cycles,#4*T9CYCLE
t9fetch 4
;@----------------------------------------------------------------------------
sngJRL_nz: ;@ 0x7E Jump Relative Long, Not Zero
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
ldrsb r1,[t9pc],#1
orr r0,r0,r1,lsl#8
tst t9f,#PSR_Z
addeq t9pc,t9pc,r0
subeq t9cycles,t9cycles,#4*T9CYCLE
t9fetch 4
;@----------------------------------------------------------------------------
sngJRL_nc: ;@ 0x7F Jump Relative Long, Not Carry
;@----------------------------------------------------------------------------
ldrb r0,[t9pc],#1
ldrsb r1,[t9pc],#1
orr r0,r0,r1,lsl#8
tst t9f,#PSR_C
addeq t9pc,t9pc,r0
subeq t9cycles,t9cycles,#4*T9CYCLE
t9fetch 4
;@----------------------------------------------------------------------------
sngLDX: ;@ 0xF7 Load eXtract
;@----------------------------------------------------------------------------
add t9pc,t9pc,#1 ;@ Skip 1 byte
ldrb t9Mem,[t9pc],#2 ;@ Skip more
ldrb r0,[t9pc],#2 ;@ Skip even more
bl t9StoreB_Low
t9fetch 9
;@----------------------------------------------------------------------------
;@sngSWI_0: ;@ 0xF8 Reset.
;@----------------------------------------------------------------------------
;@sngSWI_1: ;@ 0xF9 System call handler/Default interrupt.
;@----------------------------------------------------------------------------
sngSWI2: ;@ 0xFA Illegal instruction interrupt.
;@----------------------------------------------------------------------------
mov t9opCode,#2
;@----------------------------------------------------------------------------
;@sngSWI_3: ;@ 0xFB User SWI.
;@----------------------------------------------------------------------------
;@sngSWI_4: ;@ 0xFC User SWI.
;@----------------------------------------------------------------------------
;@sngSWI_5: ;@ 0xFD User SWI.
;@----------------------------------------------------------------------------
;@sngSWI_6: ;@ 0xFE User SWI.
;@----------------------------------------------------------------------------
;@sngSWI_7: ;@ 0xFF Unknown debug?
;@----------------------------------------------------------------------------
sngSWI:
;@----------------------------------------------------------------------------
ldr r0,[t9ptr,#tlcsLastBank]
sub r0,t9pc,r0
bl push32
bl pushSR
ldr r1,=0xFFFF00 ;@ Interrupt vector
and r0,t9opCode,#0x07
add r0,r1,r0,lsl#2
bl t9LoadL
bl encode_r0_pc
t9fetch 19
;@----------------------------------------------------------------------------
#endif // #ifdef __arm__