build.gradle

plugins {
    id 'org.springframework.boot' version '2.7.3'
    id 'io.spring.dependency-management' version '1.0.13.RELEASE'
    id 'net.kyori.indra.git' version '2.1.1'
    id 'java'
}

sourceCompatibility = '17'
targetCompatibility = '17'

group 'dev.vankka'
version '2'

repositories {
    mavenCentral()
}

dependencies {
    // Spring (application framework, web server)
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.boot:spring-boot-starter-security'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'

    // Swagger
    implementation 'io.springfox:springfox-swagger2:3.0.0'
    implementation 'io.springfox:springfox-swagger-ui:3.0.0'
    implementation 'io.springfox:springfox-boot-starter:3.0.0'

    // Apache commons
    implementation 'commons-io:commons-io:2.11.0'
    implementation 'org.apache.commons:commons-lang3:3.12.0'
    implementation 'org.apache.commons:commons-collections4:4.4'

    // Caffeine (Cache)
    implementation 'com.github.ben-manes.caffeine:caffeine:3.1.2'

    // Bucket4j (Rate limiting)
    implementation 'com.bucket4j:bucket4j-core:8.1.1'
    implementation 'com.bucket4j:bucket4j-caffeine:8.1.1'

    // Jackson (JSON)
    implementation 'com.fasterxml.jackson.core:jackson-databind:2.14.0'

    // okhttp (http requests)
    implementation 'com.squareup.okhttp3:okhttp:4.10.0'

    // Discord webhooks
    implementation 'club.minnced:discord-webhooks:0.8.2'

    // H2 database driver (stats)
    implementation 'com.h2database:h2:2.1.214'

    // SLF4J logging impl
    implementation 'org.slf4j:slf4j-simple:2.0.4'

    // org.json (v1 routes)
    implementation 'org.json:json:20220924'
}

jar {
    archiveFileName = 'DiscordSRVDownloader.jar'
    from configurations.runtimeClasspath.collect {
        it.getName().endsWith('.jar') ? zipTree(it) : it
    }

    duplicatesStrategy = DuplicatesStrategy.EXCLUDE

    manifest {
        attributes(
                'Main-Class': 'dev.vankka.dsrvdownloader.Downloader'
        )
    }
}

tasks.withType(Jar.class) {
    manifest {
        var commit = indraGit.isPresent() ? indraGit.commit() : null
        attributes(
                'Git-Revision': commit != null ? commit.name() : ''
        )
    }
}