build.gradle

plugins {
    id 'java'
    id "signing"
    id "maven-publish"
    id "io.github.gradle-nexus.publish-plugin" version "1.1.0"
}

version = "${project_version}" + (isSnapshot() ? '+' + getBuildNumber() : '')
description = 'An API lib to make requests to NodeCDN'

sourceCompatibility = 1.8
targetCompatibility = 1.8

repositories {
    mavenCentral()
}

dependencies {
    implementation group: 'io.github.openfeign', name: 'feign-okhttp', version: '11.2'
    implementation group: 'io.github.openfeign', name: 'feign-gson', version: '11.2'
    implementation group: 'io.github.openfeign', name: 'feign-slf4j', version: '11.2'

    testImplementation group: 'org.junit.jupiter', name: 'junit-jupiter-api', version: '5.7.2'
    testImplementation group: 'io.github.openfeign', name: 'feign-mock', version: '11.2'
}

//test {
//    useJUnitPlatform()
//}

task sourcesJar(type: Jar, dependsOn: classes) {
    description = 'Creates a JAR containing the source code.'
    from sourceSets.main.allSource
    archiveClassifier = 'sources'
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    description = 'Creates a JAR containing the JavaDocs.'
    from javadoc.destinationDir
    archiveClassifier = 'javadoc'
}

artifacts {
    archives sourcesJar
    archives javadocJar
}

jar {
    manifest {
        attributes([
                'Timestamp'               : System.currentTimeMillis(),
                'Specification-Title'     : project.archivesBaseName,
                'Specification-Vendor'    : project.vendor,
                'Specification-Version'   : project.version,
                'Implementation-Title'    : project.archivesBaseName,
                'Implementation-Version'  : project.version,
                'Implementation-Vendor'   : project.vendor,
                'Implementation-Timestamp': new Date().format("yyyy-MM-dd'T'HH:mm:ssZ"),
                'Built-On-Java'           : "${System.getProperty('java.vm.version')} (${System.getProperty('java.vm.vendor')})"
        ])
    }
}

gradle.taskGraph.whenReady { taskGraph ->
    ext."signing.gnupg.keyName" = "A35B3CEC"
}

signing {
    useGpgCmd()
    sign configurations.archives
}

tasks.withType(Sign) {
    onlyIf { !isSnapshot() }
}

nexusPublishing {
    packageGroup = "com.diluv"
    repositories {
        sonatype {
            stagingProfileId = "1282c5e0d73bd2"
            username = System.getenv("OSSRH_USERNAME")
            password = System.getenv("OSSRH_PASSWORD")
        }
    }

    transitionCheckOptions {
        maxRetries.set(40)
        delayBetween.set(java.time.Duration.ofMillis(5000))
    }
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            group = project.group
            artifactId = project.name
            version = project.version

            from components.java
            artifact sourcesJar
            artifact javadocJar

            pom {
                name = project.name
                description = project.description
                url = 'https://github.com/Diluv/NodeCDN-Api'

                scm {
                    connection = 'scm:git:git://github.com/Diluv/NodeCDN-Api.git'
                    developerConnection = 'scm:git:ssh://github.com/Diluv/NodeCDN-Api.git'
                    url = 'https://github.com/Diluv/NodeCDN-Api'
                }

                licenses {
                    license {
                        name = 'GNU Lesser General Public License v2.1'
                        url = 'https://www.gnu.org/licenses/old-licenses/lgpl-2.1.en.html'
                    }
                }

                developers {
                    developer {
                        id = 'lclc98'
                        name = 'lclc98'
                        email = 'lclc98@lclc98.com'
                    }
                }
            }
        }
    }
}

static String getBuildNumber() {
    return System.getenv("GITHUB_RUN_NUMBER") ?: "0"
}

static boolean isSnapshot() {
    String ref = System.getenv("GITHUB_REF");
    if (ref != null && ref.startsWith("refs/tags/v")) {
        return false
    }
    return true
}