build.gradle

plugins {
    id 'java'
    id 'com.github.johnrengelman.shadow' version '6.1.0'
}

group 'com.danifoldi'
version '1.2.2'
sourceCompatibility = JavaVersion.VERSION_11

repositories {
    mavenCentral()
    maven { url 'https://jitpack.io/' }
    maven { url 'https://papermc.io/repo/repository/maven-public/' }
    maven { url 'https://mvn.exceptionflug.de/repository/exceptionflug-public/' }
}

dependencies {
    compileOnly 'io.github.waterfallmc:waterfall-api:1.16-R0.4-SNAPSHOT'
    compileOnly 'de.exceptionflug:protocolize-api:1.6.8-SNAPSHOT'
    compileOnly 'de.exceptionflug:protocolize-items:1.6.7-SNAPSHOT'
    compileOnly 'de.exceptionflug:protocolize-inventory:1.6.7-SNAPSHOT'
    compileOnly 'de.exceptionflug:protocolize-world:1.6.8-SNAPSHOT'

    compileOnly 'net.luckperms:api:5.3'
    compileOnly 'com.github.LeonMangler:PremiumVanishAPI:2.6.3'

    implementation ('com.electronwill.night-config:yaml:3.6.0') {
        exclude module: 'snakeyaml'
    }

    implementation'org.jetbrains:annotations:20.1.0'
    implementation 'javax.inject:javax.inject:1'
    implementation 'com.google.dagger:dagger:2.35.1'
    annotationProcessor 'com.google.dagger:dagger-compiler:2.35.1'

}

processResources {
    from(sourceSets.main.resources) {
        expand version: project.version
    }
}

shadowJar {
    minimize {
        exclude(dependency('com.electronwill.night-config:.*:.*'))
    }

    relocate 'org.jetbrains.annotations', 'com.danifoldi.bungeegui.lib.annotations'
    relocate 'javax.inject', 'com.danifoldi.bungeegui.lib.inject'
    relocate 'dagger', 'com.danifoldi.bungeegui.lib.dagger'
    archiveFileName.set("${project.name}-${project.version}.jar")
}