forked from QuiteRSS/quiterss
-
Notifications
You must be signed in to change notification settings - Fork 0
/
QuiteRSS.pro
365 lines (326 loc) · 10.3 KB
/
QuiteRSS.pro
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
# VCS revision info
REVFILE = src/VersionRev.h
QMAKE_DISTCLEAN += $$REVFILE
exists(.git) {
VERSION_REV = $$system(git rev-list master --count)
count(VERSION_REV, 1) {
os2|win32|mac {
# FIXME
VERSION_REV = $$VERSION_REV
} else {
VERSION_REV = git-$$VERSION_REV-$$system(git rev-parse --short HEAD)
}
} else {
VERSION_REV = 0
}
!build_pass:message(VCS revision: $$VERSION_REV)
os2|win32 {
system(echo $${LITERAL_HASH}define VCS_REVISION $$VERSION_REV > $$REVFILE)
} else {
system(echo \\$${LITERAL_HASH}define VCS_REVISION \\\"$$VERSION_REV\\\" > $$REVFILE)
}
} else:!exists($$REVFILE) {
VERSION_REV = 0
!build_pass:message(VCS revision: $$VERSION_REV)
os2|win32 {
system(echo $${LITERAL_HASH}define VCS_REVISION $$VERSION_REV > $$REVFILE)
} else {
system(echo \\$${LITERAL_HASH}define VCS_REVISION \\\"$$VERSION_REV\\\" > $$REVFILE)
}
}
isEqual(QT_MAJOR_VERSION, 5) {
QT += widgets webkitwidgets network xml printsupport sql multimedia
DEFINES += HAVE_QT5
equals(WEBKIT_ALPHA, true) {
DEFINES += WEBKIT_ALPHA
}
} else {
QT += core gui network xml webkit sql
os2 {
DISABLE_PHONON = 1
}
isEmpty(DISABLE_PHONON) {
QT += phonon
DEFINES += HAVE_PHONON
}
}
unix:!mac:DEFINES += HAVE_X11
TEMPLATE = app
HEADERS += \
src/VersionNo.h \
src/parseobject.h \
src/optionsdialog.h \
src/newsview/newsview.h \
src/newsview/newsmodel.h \
src/newsview/newsheader.h \
src/aboutdialog.h \
src/updateappdialog.h \
src/feedpropertiesdialog.h \
src/addfeedwizard.h \
src/newstabwidget.h \
src/findtext.h \
src/findfeed.h \
src/feedsview/feedsview.h \
src/feedsview/feedsmodel.h \
src/VersionRev.h \
src/addfolderdialog.h \
src/labeldialog.h \
src/faviconobject.h \
src/customizetoolbardialog.h \
src/plugins/webpluginfactory.h \
src/plugins/clicktoflash.h \
src/downloads/downloadmanager.h \
src/downloads/downloaditem.h \
src/tabbar.h \
src/categoriestreewidget.h \
src/cleanupwizard.h \
src/updatefeeds.h \
src/requestfeed.h \
src/notifications/notificationsfeeditem.h \
src/notifications/notificationsnewsitem.h \
src/notifications/notificationswidget.h \
src/application/mainapplication.h \
src/application/settings.h \
src/application/logfile.h \
src/application/mainwindow.h \
src/adblock/adblocktreewidget.h \
src/adblock/adblocksubscription.h \
src/adblock/adblocksearchtree.h \
src/adblock/adblockrule.h \
src/adblock/adblockmanager.h \
src/adblock/adblockicon.h \
src/adblock/adblockdialog.h \
src/adblock/adblockblockednetworkreply.h \
src/adblock/adblockaddsubscriptiondialog.h \
src/adblock/followredirectreply.h \
src/application/splashscreen.h \
src/network/authenticationdialog.h \
src/network/cookiejar.h \
src/network/networkmanager.h \
src/webview/locationbar.h \
src/webview/rssdetectionwidget.h \
src/webview/webpage.h \
src/webview/webview.h \
src/database/database.h \
src/common/common.h \
src/common/delegatewithoutfocus.h \
src/common/dialog.h \
src/common/lineedit.h \
src/common/toolbutton.h \
src/newsfilters/filterrulesdialog.h \
src/newsfilters/newsfiltersdialog.h \
src/newsfilters/itemcondition.h \
src/newsfilters/itemaction.h \
src/network/sslerrordialog.h \
src/network/networkmanagerproxy.h \
src/adblock/adblockmatcher.h \
src/feedsview/feedsproxymodel.h \
src/main/globals.h \
SOURCES += \
src/parseobject.cpp \
src/optionsdialog.cpp \
src/newsview/newsview.cpp \
src/newsview/newsmodel.cpp \
src/newsview/newsheader.cpp \
src/aboutdialog.cpp \
src/updateappdialog.cpp \
src/feedpropertiesdialog.cpp \
src/addfeedwizard.cpp \
src/newstabwidget.cpp \
src/findtext.cpp \
src/findfeed.cpp \
src/feedsview/feedsview.cpp \
src/feedsview/feedsmodel.cpp \
src/addfolderdialog.cpp \
src/labeldialog.cpp \
src/faviconobject.cpp \
src/customizetoolbardialog.cpp \
src/plugins/webpluginfactory.cpp \
src/plugins/clicktoflash.cpp \
src/downloads/downloadmanager.cpp \
src/downloads/downloaditem.cpp \
src/tabbar.cpp \
src/categoriestreewidget.cpp \
src/cleanupwizard.cpp \
src/updatefeeds.cpp \
src/requestfeed.cpp \
src/notifications/notificationsfeeditem.cpp \
src/notifications/notificationsnewsitem.cpp \
src/notifications/notificationswidget.cpp \
src/application/mainapplication.cpp \
src/application/settings.cpp \
src/application/logfile.cpp \
src/application/mainwindow.cpp \
src/main/globals.cpp \
src/main/main.cpp \
src/adblock/adblocktreewidget.cpp \
src/adblock/adblocksubscription.cpp \
src/adblock/adblocksearchtree.cpp \
src/adblock/adblockrule.cpp \
src/adblock/adblockmanager.cpp \
src/adblock/adblockicon.cpp \
src/adblock/adblockdialog.cpp \
src/adblock/adblockblockednetworkreply.cpp \
src/adblock/adblockaddsubscriptiondialog.cpp \
src/adblock/followredirectreply.cpp \
src/application/splashscreen.cpp \
src/network/authenticationdialog.cpp \
src/network/cookiejar.cpp \
src/network/networkmanager.cpp \
src/webview/locationbar.cpp \
src/webview/rssdetectionwidget.cpp \
src/webview/webpage.cpp \
src/webview/webview.cpp \
src/database/database.cpp \
src/common/common.cpp \
src/common/delegatewithoutfocus.cpp \
src/common/dialog.cpp \
src/common/lineedit.cpp \
src/common/toolbutton.cpp \
src/newsfilters/filterrulesdialog.cpp \
src/newsfilters/newsfiltersdialog.cpp \
src/newsfilters/itemcondition.cpp \
src/newsfilters/itemaction.cpp \
src/network/sslerrordialog.cpp \
src/network/networkmanagerproxy.cpp \
src/adblock/adblockmatcher.cpp \
src/feedsview/feedsproxymodel.cpp
INCLUDEPATH += $$PWD/src \
$$PWD/src/application \
$$PWD/src/common \
$$PWD/src/main \
$$PWD/src/database \
$$PWD/src/downloads \
$$PWD/src/feedsview \
$$PWD/src/newsfilters \
$$PWD/src/newsview \
$$PWD/src/notifications \
$$PWD/src/plugins \
$$PWD/src/adblock \
$$PWD/src/network \
$$PWD/src/webview \
CONFIG += debug_and_release
CONFIG(debug, debug|release) {
BUILD_DIR = $$OUT_PWD/debug
} else {
BUILD_DIR = $$OUT_PWD/release
# DEFINES += QT_NO_DEBUG_OUTPUT
}
DESTDIR = $${BUILD_DIR}/target
OBJECTS_DIR = $${BUILD_DIR}/obj
MOC_DIR = $${BUILD_DIR}/moc
RCC_DIR = $${BUILD_DIR}/rcc
isEmpty(SYSTEMQTSA) {
include(3rdparty/qtsingleapplication/qtsingleapplication.pri)
} else {
CONFIG += qtsingleapplication
}
isEqual(QT_MAJOR_VERSION, 5) {
include(3rdparty/qftp/qftp.pri)
}
include(3rdparty/sqlite.pri)
include(lang/lang.pri)
include(3rdparty/qupzilla/qupzilla.pri)
include(3rdparty/ganalytics/ganalytics.pri)
os2|win32|mac {
TARGET = QuiteRSS
}
win32 {
RC_FILE = QuiteRSSApp.rc
}
win32-g++ {
LIBS += libkernel32 \
libpsapi
}
win32-msvc* {
LIBS += -lpsapi
LIBS += -lShell32
LIBS += -lUser32
QMAKE_CXXFLAGS += -D__PRETTY_FUNCTION__=__FUNCTION__
QMAKE_CFLAGS += -D__PRETTY_FUNCTION__=__FUNCTION__
}
os2 {
RC_FILE = quiterss_os2.rc
}
os2|win32 {
SOURCES += src/network/cabundleupdater.cpp
HEADERS += src/network/cabundleupdater.h
RESOURCES += data/ca-bundle.qrc
}
DISTFILES += \
HISTORY_RU \
HISTORY_EN \
COPYING \
AUTHORS \
CHANGELOG \
README.md
unix:!mac {
TARGET = quiterss
isEmpty(PREFIX) {
PREFIX = /usr/local
}
DATA_DIR = $$PREFIX/share/quiterss
DEFINES += RESOURCES_DIR='\\\"$${DATA_DIR}\\\"'
target.path = $$quote($$PREFIX/bin)
desktop.files = quiterss.desktop
desktop.path = $$quote($$PREFIX/share/applications)
appdata.files = quiterss.appdata.xml
appdata.path = $$quote($$PREFIX/share/metainfo)
target1.files = images/48x48/quiterss.png
target1.path = $$quote($$PREFIX/share/pixmaps)
icon_16.files = images/16x16/quiterss.png
icon_32.files = images/32x32/quiterss.png
icon_48.files = images/48x48/quiterss.png
icon_64.files = images/64x64/quiterss.png
icon_128.files = images/128x128/quiterss.png
icon_256.files = images/256x256/quiterss.png
icon_16.path = $$quote($$PREFIX/share/icons/hicolor/16x16/apps)
icon_32.path = $$quote($$PREFIX/share/icons/hicolor/32x32/apps)
icon_48.path = $$quote($$PREFIX/share/icons/hicolor/48x48/apps)
icon_64.path = $$quote($$PREFIX/share/icons/hicolor/64x64/apps)
icon_128.path = $$quote($$PREFIX/share/icons/hicolor/128x128/apps)
icon_256.path = $$quote($$PREFIX/share/icons/hicolor/256x256/apps)
translations.files = $$quote($$DESTDIR/lang)
translations.path = $$quote($$DATA_DIR)
translations.CONFIG += no_check_exist
sound.files = sound
sound.path = $$quote($$DATA_DIR)
style.files = style
style.path = $$quote($$DATA_DIR)
INSTALLS += target desktop appdata target1
INSTALLS += icon_16 icon_32 icon_48 icon_64 icon_128 icon_256
INSTALLS += translations sound style
}
mac {
CONFIG += app_bundle
QMAKE_MACOSX_DEPLOYMENT_TARGET = 10.6
QMAKE_INFO_PLIST = Info.plist
ICON = quiterss.icns
bundle_target.files += AUTHORS
bundle_target.files += COPYING
bundle_target.files += CHANGELOG
bundle_target.files += README.md
bundle_target.files += sound
bundle_target.files += style
bundle_target.path = Contents/Resources
QMAKE_BUNDLE_DATA += bundle_target
translations.files = $$quote($$DESTDIR/lang)
translations.path = Contents/Resources
QMAKE_BUNDLE_DATA += translations
INSTALLS += bundle_target translations
}
RESOURCES += \
QuiteRSS.qrc
CODECFORTR = UTF-8
CODECFORSRC = UTF-8
OTHER_FILES += \
HISTORY_RU \
HISTORY_EN \
COPYING \
AUTHORS \
CHANGELOG \
INSTALL \
Info.plist
FORMS += \
src/adblock/adblockdialog.ui \
src/adblock/adblockaddsubscriptiondialog.ui