CMakeLists.txt

CMAKE_MINIMUM_REQUIRED(VERSION 2.8.6)

PROJECT(WiiYourself)
INCLUDE(GenerateExportHeader)

SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${PROJECT_SOURCE_DIR}/cmake/")

#Installation directory for executables
SET(INSTALL_BIN_DIR "${CMAKE_INSTALL_PREFIX}/bin")
#Installation directory for libraries
SET(INSTALL_LIB_DIR "${CMAKE_INSTALL_PREFIX}/lib")
#Installation directory for headers
SET(INSTALL_INC_DIR "${CMAKE_INSTALL_PREFIX}/include")

SET(WDK_ROOT "C:/WinDDK/7600.16385.1" CACHE PATH "Default WDK path")

FIND_PACKAGE(WDK REQUIRED)

# Allow the developer to select if Dynamic or Static libraries are built
OPTION(BUILD_SHARED_LIBS "Build Shared Libraries" ON)

IF(BUILD_SHARED_LIBS)
    SET(LIB_TYPE SHARED)
ELSE(BUILD_SHARED_LIBS)
    SET(LIB_TYPE STATIC)
ENDIF(BUILD_SHARED_LIBS)

SET(WIIYOURSELF_SOURCE_FILES
	wiimote.cpp
)
SET(WIIYOURSELF_HEADER_FILES
	${PROJECT_SOURCE_DIR}/wiimote.h
	${PROJECT_SOURCE_DIR}/wiimote_common.h
	${PROJECT_SOURCE_DIR}/wiimote_state.h
)

INCLUDE_DIRECTORIES(${WDK_INCLUDE_DIRS} ${CMAKE_BINARY_DIR})

ADD_LIBRARY(WiiYourself ${LIB_TYPE} ${WIIYOURSELF_SOURCE_FILES} ${WIIYOURSELF_HEADER_FILES})
TARGET_LINK_LIBRARIES(WiiYourself ${WDK_LIBRARIES})
    
GENERATE_EXPORT_HEADER( WiiYourself
             BASE_NAME WIIYOURSELF
             EXPORT_MACRO_NAME WIIYOURSELF_EXPORT
             EXPORT_FILE_NAME WiiYourself_Export.h
             STATIC_DEFINE WIIYOURSELF_BUILT_AS_STATIC
)


OPTION(BUILD_DEMO "Build the demo" OFF)
IF(BUILD_DEMO)
    ADD_SUBDIRECTORY(Demo)
ENDIF(BUILD_DEMO)

INSTALL(TARGETS WiiYourself
        RUNTIME DESTINATION "${INSTALL_BIN_DIR}"
        ARCHIVE DESTINATION "${INSTALL_LIB_DIR}"
        LIBRARY DESTINATION "${INSTALL_LIB_DIR}" )
        
FILE(GLOB INC_FILES "${CMAKE_CURRENT_SOURCE_DIR}/*.h")
INSTALL(FILES ${INC_FILES} ${PROJECT_BINARY_DIR}/WiiYourself_export.h DESTINATION "${INSTALL_INC_DIR}")