forked from qubka/Zombie-Plague
-
Notifications
You must be signed in to change notification settings - Fork 0
/
zp_zclasses_witch.sp
336 lines (279 loc) · 10.3 KB
/
zp_zclasses_witch.sp
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
/**
* ============================================================================
*
* Zombie Plague
*
*
* Copyright (C) 2015-2020 Nikita Ushakov (Ireland, Dublin)
*
* This program is free software: you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation, either version 3 of the License, or
* (at your option) any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program. If not, see <http://www.gnu.org/licenses/>.
*
* ============================================================================
**/
#include <sourcemod>
#include <sdktools>
#include <sdkhooks>
#include <zombieplague>
#pragma newdecls required
#pragma semicolon 1
/**
* @brief Record plugin info.
**/
public Plugin myinfo =
{
name = "[ZP] Zombie Class: Witch",
author = "qubka (Nikita Ushakov)",
description = "Addon of zombie classses",
version = "1.0",
url = "https://forums.alliedmods.net/showthread.php?t=290657"
}
/**
* @section Information about the zombie class.
**/
#define ZOMBIE_CLASS_SKILL_SPEED 1500.0
#define ZOMBIE_CLASS_SKILL_GRAVITY 0.01
#define ZOMBIE_CLASS_SKILL_ATTACH 150.0 // Attach speed
#define ZOMBIE_CLASS_SKILL_DURATION 4.0
#define ZOMBIE_CLASS_SKILL_EXP_TIME 2.0
/**
* @endsection
**/
// Decal index
int gSmoke;
#pragma unused gSmoke
// Sound index
int gSound; ConVar hSoundLevel;
#pragma unused gSound, hSoundLevel
// Zombie index
int gZombie;
#pragma unused gZombie
/**
* @brief Called after a library is added that the current plugin references optionally.
* A library is either a plugin name or extension name, as exposed via its include file.
**/
public void OnLibraryAdded(const char[] sLibrary)
{
// Validate library
if (!strcmp(sLibrary, "zombieplague", false))
{
// If map loaded, then run custom forward
if (ZP_IsMapLoaded())
{
// Execute it
ZP_OnEngineExecute();
}
}
}
/**
* @brief Called after a zombie core is loaded.
**/
public void ZP_OnEngineExecute(/*void*/)
{
// Classes
gZombie = ZP_GetClassNameID("witch");
//if (gZombie == -1) SetFailState("[ZP] Custom zombie class ID from name : \"witch\" wasn't find");
// Sounds
gSound = ZP_GetSoundKeyID("WITCH_SKILL_SOUNDS");
if (gSound == -1) SetFailState("[ZP] Custom sound key ID from name : \"WITCH_SKILL_SOUNDS\" wasn't find");
// Cvars
hSoundLevel = FindConVar("zp_seffects_level");
if (hSoundLevel == null) SetFailState("[ZP] Custom cvar key ID from name : \"zp_seffects_level\" wasn't find");
}
/**
* @brief The map is starting.
**/
public void OnMapStart(/*void*/)
{
// Models
gSmoke = PrecacheModel("sprites/steam1.vmt", true);
}
/**
* @brief Called when a client use a skill.
*
* @param client The client index.
*
* @return Plugin_Handled to block using skill. Anything else
* (like Plugin_Continue) to allow use.
**/
public Action ZP_OnClientSkillUsed(int client)
{
// Validate the zombie class index
if (ZP_GetClientClass(client) == gZombie)
{
// Initialize vectors
static float vPosition[3]; static float vAngle[3]; static float vVelocity[3]; static float vSpeed[3];
// Gets client eye position
GetClientEyePosition(client, vPosition);
// Gets client eye angle
GetClientEyeAngles(client, vAngle);
// Gets client speed
GetEntPropVector(client, Prop_Data, "m_vecVelocity", vVelocity);
// Play sound
ZP_EmitSoundToAll(gSound, 1, client, SNDCHAN_VOICE, hSoundLevel.IntValue);
// Create a bat entity
int entity = UTIL_CreateProjectile(vPosition, vAngle, "models/weapons/cso/bazooka/w_bazooka_projectile.mdl");
// Validate entity
if (entity != -1)
{
// Sets bat model scale
SetEntPropFloat(entity, Prop_Send, "m_flModelScale", 9.0);
// Returns vectors in the direction of an angle
GetAngleVectors(vAngle, vSpeed, NULL_VECTOR, NULL_VECTOR);
// Normalize the vector (equal magnitude at varying distances)
NormalizeVector(vSpeed, vSpeed);
// Apply the magnitude by scaling the vector
ScaleVector(vSpeed, ZOMBIE_CLASS_SKILL_SPEED);
// Adds two vectors
AddVectors(vSpeed, vVelocity, vSpeed);
// Push the bat
TeleportEntity(entity, NULL_VECTOR, NULL_VECTOR, vSpeed);
// Sets an entity color
UTIL_SetRenderColor(entity, Color_Alpha, 0);
AcceptEntityInput(entity, "DisableShadow"); /// Prevents the entity from receiving shadows
// Create a prop_dynamic_override entity
int bat = UTIL_CreateDynamic("bats", NULL_VECTOR, NULL_VECTOR, "models/player/custom_player/zombie/bats/bats2.mdl", "fly", false);
// Validate entity
if (bat != -1)
{
// Sets parent to the entity
SetVariantString("!activator");
AcceptEntityInput(bat, "SetParent", entity, bat);
// Sets attachment to the projectile
SetVariantString("1");
AcceptEntityInput(bat, "SetParentAttachment", entity, bat);
}
// Sets parent for the entity
SetEntPropEnt(entity, Prop_Data, "m_pParent", client);
SetEntPropEnt(entity, Prop_Data, "m_hOwnerEntity", client);
SetEntPropEnt(entity, Prop_Data, "m_hThrower", client);
// Sets gravity
SetEntPropFloat(entity, Prop_Data, "m_flGravity", ZOMBIE_CLASS_SKILL_GRAVITY);
// Create touch hook
SDKHook(entity, SDKHook_Touch, BatTouchHook);
}
}
// Allow usage
return Plugin_Continue;
}
/**
* @brief Bat touch hook.
*
* @param entity The entity index.
* @param target The target index.
**/
public Action BatTouchHook(int entity, int target)
{
// Validate target
if (IsValidEdict(target))
{
// Gets thrower index
int thrower = GetEntPropEnt(entity, Prop_Data, "m_hThrower");
// Validate thrower
if (thrower == target)
{
// Return on the unsuccess
return Plugin_Continue;
}
// Gets entity position
static float vPosition[3];
GetEntPropVector(entity, Prop_Data, "m_vecAbsOrigin", vPosition);
// Validate target
if (IsPlayerExist(target))
{
// Create a prop_dynamic_override entity
int bat = UTIL_CreateDynamic("bats", NULL_VECTOR, NULL_VECTOR, "models/player/custom_player/zombie/bats/bats2.mdl", "fly2", false);
// Validate entity
if (bat != -1)
{
// Sets parent to the entity
SetVariantString("!activator");
AcceptEntityInput(bat, "SetParent", target, bat);
SetEntPropEnt(bat, Prop_Data, "m_pParent", target);
if (thrower != -1)
{
SetEntPropEnt(bat, Prop_Data, "m_hOwnerEntity", thrower);
}
// Sets attachment to the client
SetVariantString("eholster");
AcceptEntityInput(bat, "SetParentAttachment", target, bat);
// Kill after some duration
UTIL_RemoveEntity(bat, ZOMBIE_CLASS_SKILL_DURATION);
// Create a attach timer
CreateTimer(0.1, BatAttachHook, EntIndexToEntRef(bat), TIMER_REPEAT | TIMER_FLAG_NO_MAPCHANGE);
}
// Play sound
ZP_EmitSoundToAll(gSound, 2, target, SNDCHAN_VOICE, hSoundLevel.IntValue);
}
else
{
// Create an blood effect
UTIL_CreateParticle(_, vPosition, _, _, "blood_pool", ZOMBIE_CLASS_SKILL_EXP_TIME);
// Play sound
ZP_EmitSoundToAll(gSound, 3, entity, SNDCHAN_STATIC, hSoundLevel.IntValue);
// Create effect
TE_SetupSmoke(vPosition, gSmoke, 130.0, 10);
TE_SendToAll();
}
// Remove entity from world
AcceptEntityInput(entity, "Kill");
}
// Return on the success
return Plugin_Continue;
}
/**
* @brief Main timer for attach bat hook.
*
* @param hTimer The timer handle.
* @param refID The reference index.
**/
public Action BatAttachHook(Handle hTimer, int refID)
{
// Gets entity index from reference key
int entity = EntRefToEntIndex(refID);
// Validate entity
if (entity != -1)
{
// Gets owner/target index
int owner = GetEntPropEnt(entity, Prop_Data, "m_hOwnerEntity");
int target = GetEntPropEnt(entity, Prop_Data, "m_pParent");
// Validate owner/target
if (IsPlayerExist(owner) && IsPlayerExist(target))
{
// Initialize vectors
static float vPosition[3]; static float vAngle[3]; static float vVelocity[3];
// Gets owner/target eye position
GetClientEyePosition(owner, vPosition);
GetClientEyePosition(target, vAngle);
// Calculate the velocity vector
MakeVectorFromPoints(vAngle, vPosition, vVelocity);
// Block vertical scale
vVelocity[2] = 0.0;
// Normalize the vector (equal magnitude at varying distances)
NormalizeVector(vVelocity, vVelocity);
// Apply the magnitude by scaling the vector
ScaleVector(vVelocity, ZOMBIE_CLASS_SKILL_ATTACH);
// Push the target
TeleportEntity(target, NULL_VECTOR, NULL_VECTOR, vVelocity);
// Allow timer
return Plugin_Continue;
}
else
{
// Remove entity from world
AcceptEntityInput(entity, "Kill");
}
}
// Destroy timer
return Plugin_Stop;
}