forked from qubka/Zombie-Plague
-
Notifications
You must be signed in to change notification settings - Fork 0
/
zp_weapon_sfpistol.sp
536 lines (453 loc) · 15.9 KB
/
zp_weapon_sfpistol.sp
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
/**
* ============================================================================
*
* Zombie Plague
*
*
* Copyright (C) 2015-2020 Nikita Ushakov (Ireland, Dublin)
*
* This program is free software: you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation, either version 3 of the License, or
* (at your option) any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program. If not, see <http://www.gnu.org/licenses/>.
*
* ============================================================================
**/
#include <sourcemod>
#include <sdktools>
#include <sdkhooks>
#include <zombieplague>
#pragma newdecls required
#pragma semicolon 1
/**
* @brief Record plugin info.
**/
public Plugin myinfo =
{
name = "[ZP] Weapon: SFPistol",
author = "qubka (Nikita Ushakov)",
description = "Addon of custom weapon",
version = "1.0",
url = "https://forums.alliedmods.net/showthread.php?t=290657"
}
/**
* @section Information about the weapon.
**/
#define WEAPON_BEAM_COLOR {185, 212, 11, 255}
#define WEAPON_IDLE_TIME 3.33
#define WEAPON_ATTACK_END_TIME 0.5
/**
* @endsection
**/
// Item index
int gWeapon;
#pragma unused gWeapon
// Sound index
int gSoundAttack; int gSoundIdle; ConVar hSoundLevel;
#pragma unused gSoundAttack, gSoundIdle, hSoundLevel
// Decal index
int gBeam;
#pragma unused gBeam
// Animation sequences
enum
{
ANIM_IDLE,
ANIM_ATTACK_LOOP1,
ANIM_ATTACK_LOOP2,
ANIM_DRAW,
ANIM_RELOAD,
ANIM_ATTACK_END
};
// Weapon states
enum
{
STATE_BEGIN,
STATE_ATTACK
};
/**
* @brief Called after a library is added that the current plugin references optionally.
* A library is either a plugin name or extension name, as exposed via its include file.
**/
public void OnLibraryAdded(const char[] sLibrary)
{
// Validate library
if (!strcmp(sLibrary, "zombieplague", false))
{
// If map loaded, then run custom forward
if (ZP_IsMapLoaded())
{
// Execute it
ZP_OnEngineExecute();
}
}
}
/**
* @brief Called after a zombie core is loaded.
**/
public void ZP_OnEngineExecute(/*void*/)
{
// Weapons
gWeapon = ZP_GetWeaponNameID("sfpistol");
//if (gWeapon == -1) SetFailState("[ZP] Custom weapon ID from name : \"sfpistol\" wasn't find");
// Sounds
gSoundAttack = ZP_GetSoundKeyID("SFPISTOL_SHOOT_SOUNDS");
if (gSoundAttack == -1) SetFailState("[ZP] Custom sound key ID from name : \"SFPISTOL_SHOOT_SOUNDS\" wasn't find");
gSoundIdle = ZP_GetSoundKeyID("SFPISTOL_IDLE_SOUNDS");
if (gSoundIdle == -1) SetFailState("[ZP] Custom sound key ID from name : \"SFPISTOL_IDLE_SOUNDS\" wasn't find");
// Cvars
hSoundLevel = FindConVar("zp_seffects_level");
if (hSoundLevel == null) SetFailState("[ZP] Custom cvar key ID from name : \"zp_seffects_level\" wasn't find");
}
/**
* @brief The map is starting.
**/
public void OnMapStart(/*void*/)
{
// Models
gBeam = PrecacheModel("materials/sprites/laserbeam.vmt", true);
}
//*********************************************************************
//* Don't modify the code below this line unless *
//* you know _exactly_ what you are doing!!! *
//*********************************************************************
void Weapon_OnHolster(int client, int weapon, int iClip, int iAmmo, int iStateMode, float flCurrentTime)
{
#pragma unused client, weapon, iClip, iAmmo, iStateMode, flCurrentTime
// Cancel reload
SetEntPropFloat(weapon, Prop_Send, "m_flDoneSwitchingSilencer", 0.0);
// Stop sound
ZP_EmitSoundToAll(gSoundIdle, 1, weapon, SNDCHAN_WEAPON, SNDLEVEL_NONE, SND_STOP, 0.0);
}
void Weapon_OnIdle(int client, int weapon, int iClip, int iAmmo, int iStateMode, float flCurrentTime)
{
#pragma unused client, weapon, iClip, iAmmo, iStateMode, flCurrentTime
// Validate clip
if (iClip <= 0)
{
// Validate ammo
if (iAmmo)
{
Weapon_OnReload(client, weapon, iClip, iAmmo, iStateMode, flCurrentTime);
return; /// Execute fake reload
}
}
// Validate animation delay
if (GetEntPropFloat(weapon, Prop_Send, "m_flTimeWeaponIdle") > flCurrentTime)
{
return;
}
// Sets idle animation
ZP_SetWeaponAnimation(client, ANIM_IDLE);
// Play sound
ZP_EmitSoundToAll(gSoundIdle, 1, weapon, SNDCHAN_WEAPON, SNDLEVEL_NONE, SND_STOP, 0.0);
ZP_EmitSoundToAll(gSoundIdle, 1, weapon, SNDCHAN_WEAPON, hSoundLevel.IntValue);
// Sets next idle time
SetEntPropFloat(weapon, Prop_Send, "m_flTimeWeaponIdle", flCurrentTime + WEAPON_IDLE_TIME);
}
void Weapon_OnReload(int client, int weapon, int iClip, int iAmmo, int iStateMode, float flCurrentTime)
{
#pragma unused client, weapon, iClip, iAmmo, iStateMode, flCurrentTime
// Validate clip
if (min(ZP_GetWeaponClip(gWeapon) - iClip, iAmmo) <= 0)
{
return;
}
// Validate mode
if (iStateMode > STATE_BEGIN)
{
Weapon_OnEndAttack(client, weapon, iClip, iAmmo, iStateMode, flCurrentTime);
return;
}
// Validate animation delay
if (GetEntPropFloat(weapon, Prop_Send, "m_fLastShotTime") > flCurrentTime)
{
return;
}
// Sets reload animation
ZP_SetWeaponAnimation(client, ANIM_RELOAD);
ZP_SetPlayerAnimation(client, AnimType_Reload);
// Adds the delay to the game tick
flCurrentTime += ZP_GetWeaponReload(gWeapon);
// Sets next attack time
SetEntPropFloat(weapon, Prop_Send, "m_flTimeWeaponIdle", flCurrentTime);
SetEntPropFloat(weapon, Prop_Send, "m_fLastShotTime", flCurrentTime);
// Stop sound
ZP_EmitSoundToAll(gSoundIdle, 1, weapon, SNDCHAN_WEAPON, SNDLEVEL_NONE, SND_STOP, 0.0);
// Remove the delay to the game tick
flCurrentTime -= 0.5;
// Sets reloading time
SetEntPropFloat(weapon, Prop_Send, "m_flDoneSwitchingSilencer", flCurrentTime);
}
void Weapon_OnReloadFinish(int client, int weapon, int iClip, int iAmmo, int iStateMode, float flCurrentTime)
{
#pragma unused client, weapon, iClip, iAmmo, iStateMode, flCurrentTime
// Gets new amount
int iAmount = min(ZP_GetWeaponClip(gWeapon) - iClip, iAmmo);
// Sets ammunition
SetEntProp(weapon, Prop_Send, "m_iClip1", iClip + iAmount);
SetEntProp(weapon, Prop_Send, "m_iPrimaryReserveAmmoCount", iAmmo - iAmount);
// Sets reload time
SetEntPropFloat(weapon, Prop_Send, "m_flDoneSwitchingSilencer", 0.0);
}
void Weapon_OnDeploy(int client, int weapon, int iClip, int iAmmo, int iStateMode, float flCurrentTime)
{
#pragma unused client, weapon, iClip, iAmmo, iStateMode, flCurrentTime
/// Block the real attack
SetEntPropFloat(client, Prop_Send, "m_flNextAttack", MAX_FLOAT);
SetEntPropFloat(weapon, Prop_Send, "m_flNextPrimaryAttack", MAX_FLOAT);
// Sets draw animation
ZP_SetWeaponAnimation(client, ANIM_DRAW);
// Sets attack state
SetEntProp(weapon, Prop_Data, "m_iHealth", STATE_BEGIN);
// Sets next attack time
SetEntPropFloat(weapon, Prop_Send, "m_fLastShotTime", flCurrentTime + ZP_GetWeaponDeploy(gWeapon));
}
void Weapon_OnPrimaryAttack(int client, int weapon, int iClip, int iAmmo, int iStateMode, float flCurrentTime)
{
#pragma unused client, weapon, iClip, iAmmo, iStateMode, flCurrentTime
// Validate clip
if (iClip <= 0)
{
// Validate mode
if (iStateMode > STATE_BEGIN)
{
Weapon_OnEndAttack(client, weapon, iClip, iAmmo, iStateMode, flCurrentTime);
}
return;
}
// Validate animation delay
if (GetEntPropFloat(weapon, Prop_Send, "m_fLastShotTime") > flCurrentTime)
{
return;
}
// Validate water
if (GetEntProp(client, Prop_Data, "m_nWaterLevel") == WLEVEL_CSGO_FULL)
{
Weapon_OnEndAttack(client, weapon, iClip, iAmmo, iStateMode, flCurrentTime);
return;
}
// Sets attack animation
ZP_SetWeaponAnimationPair(client, weapon, { ANIM_ATTACK_LOOP1, ANIM_ATTACK_LOOP2 });
ZP_SetPlayerAnimation(client, AnimType_FirePrimary);
// Sets attack state
SetEntProp(weapon, Prop_Data, "m_iHealth", STATE_ATTACK);
// Substract ammo
iClip -= 1; SetEntProp(weapon, Prop_Send, "m_iClip1", iClip); if (!iClip)
{
Weapon_OnEndAttack(client, weapon, iClip, iAmmo, iStateMode, flCurrentTime);
return;
}
// Play sound
ZP_EmitSoundToAll(gSoundIdle, 1, weapon, SNDCHAN_WEAPON, SNDLEVEL_NONE, SND_STOP, 0.0);
ZP_EmitSoundToAll(gSoundAttack, 1, client, SNDCHAN_WEAPON, hSoundLevel.IntValue);
// Adds the delay to the game tick
flCurrentTime += ZP_GetWeaponSpeed(gWeapon);
// Sets next attack time
SetEntPropFloat(weapon, Prop_Send, "m_flTimeWeaponIdle", flCurrentTime);
SetEntPropFloat(weapon, Prop_Send, "m_fLastShotTime", flCurrentTime);
// Create a fire
Weapon_OnCreateBeam(client, weapon);
// Gets weapon muzzleflesh
static char sMuzzle[NORMAL_LINE_LENGTH];
ZP_GetWeaponModelMuzzle(gWeapon, sMuzzle, sizeof(sMuzzle));
// Creates a muzzle
UTIL_CreateParticle(ZP_GetClientViewModel(client, true), _, _, "1", sMuzzle, 0.1);
}
void Weapon_OnCreateBeam(int client, int weapon)
{
#pragma unused client, weapon
// Initialize vectors
static float vPosition[3]; static float vEndPosition[3]; static float vAngle[3];
// Gets weapon position
ZP_GetPlayerGunPosition(client, 30.0, 3.5, -10.0, vPosition);
// Gets client eye angle
GetClientEyeAngles(client, vAngle);
// Create the end-point trace
TR_TraceRayFilter(vPosition, vAngle, (MASK_SHOT|CONTENTS_GRATE), RayType_Infinite, SelfFilter, client);
// Returns the collision position of a trace result
TR_GetEndPosition(vEndPosition);
// Emulate bullet shot
ZP_FireBullets(client, weapon, vPosition, vAngle, 0, GetRandomInt(0, 1000), 0.0, 0.0, 0.0, 0, 0.0);
// Gets beam lifetime
float flLife = ZP_GetWeaponSpeed(gWeapon);
// Sent a beam
TE_SetupBeamPoints(vPosition, vEndPosition, gBeam, 0, 0, 0, flLife, 2.0, 2.0, 10, 1.0, WEAPON_BEAM_COLOR, 30);
TE_SendToClient(client);
// Gets worldmodel index
int world = GetEntPropEnt(weapon, Prop_Send, "m_hWeaponWorldModel");
// Validate entity
if (world != -1)
{
// Gets attachment position
ZP_GetAttachment(world, "muzzle_flash", vPosition, vAngle);
// Sent a beam
TE_SetupBeamPoints(vPosition, vEndPosition, gBeam, 0, 0, 0, flLife, 2.0, 2.0, 10, 1.0, WEAPON_BEAM_COLOR, 30);
int[] iClients = new int[MaxClients]; int iCount;
for (int i = 1; i <= MaxClients; i++)
{
if (!IsPlayerExist(i, false) || i == client || IsFakeClient(i)) continue;
iClients[iCount++] = i;
}
TE_Send(iClients, iCount);
}
}
void Weapon_OnEndAttack(int client, int weapon, int iClip, int iAmmo, int iStateMode, float flCurrentTime)
{
#pragma unused client, weapon, iClip, iAmmo, iStateMode, flCurrentTime
// Validate mode
if (iStateMode > STATE_BEGIN)
{
// Sets end animation
ZP_SetWeaponAnimation(client, ANIM_ATTACK_END);
// Sets begin state
SetEntProp(weapon, Prop_Data, "m_iHealth", STATE_BEGIN);
// Adds the delay to the game tick
flCurrentTime += WEAPON_ATTACK_END_TIME;
// Sets next attack time
SetEntPropFloat(weapon, Prop_Send, "m_flTimeWeaponIdle", flCurrentTime);
SetEntPropFloat(weapon, Prop_Send, "m_fLastShotTime", flCurrentTime);
}
}
//**********************************************
//* Item (weapon) hooks. *
//**********************************************
#define _call.%0(%1,%2) \
\
Weapon_On%0 \
( \
%1, \
%2, \
\
GetEntProp(%2, Prop_Send, "m_iClip1"), \
\
GetEntProp(%2, Prop_Send, "m_iPrimaryReserveAmmoCount"), \
\
GetEntProp(%2, Prop_Data, "m_iHealth"), \
\
GetGameTime() \
)
/**
* @brief Called after a custom weapon is created.
*
* @param client The client index.
* @param weapon The weapon index.
* @param weaponID The weapon id.
**/
public void ZP_OnWeaponCreated(int client, int weapon, int weaponID)
{
// Validate custom weapon
if (weaponID == gWeapon)
{
// Resets variables
SetEntProp(weapon, Prop_Data, "m_iHealth", STATE_BEGIN);
SetEntPropFloat(weapon, Prop_Send, "m_flDoneSwitchingSilencer", 0.0);
}
}
/**
* @brief Called on deploy of a weapon.
*
* @param client The client index.
* @param weapon The weapon index.
* @param weaponID The weapon id.
**/
public void ZP_OnWeaponDeploy(int client, int weapon, int weaponID)
{
// Validate custom weapon
if (weaponID == gWeapon)
{
// Call event
_call.Deploy(client, weapon);
}
}
/**
* @brief Called on holster of a weapon.
*
* @param client The client index.
* @param weapon The weapon index.
* @param weaponID The weapon id.
**/
public void ZP_OnWeaponHolster(int client, int weapon, int weaponID)
{
// Validate custom weapon
if (weaponID == gWeapon)
{
// Call event
_call.Holster(client, weapon);
}
}
/**
* @brief Called on each frame of a weapon holding.
*
* @param client The client index.
* @param iButtons The buttons buffer.
* @param iLastButtons The last buttons buffer.
* @param weapon The weapon index.
* @param weaponID The weapon id.
*
* @return Plugin_Continue to allow buttons. Anything else
* (like Plugin_Changed) to change buttons.
**/
public Action ZP_OnWeaponRunCmd(int client, int &iButtons, int iLastButtons, int weapon, int weaponID)
{
// Validate custom weapon
if (weaponID == gWeapon)
{
// Time to reload weapon
static float flReloadTime;
if ((flReloadTime = GetEntPropFloat(weapon, Prop_Send, "m_flDoneSwitchingSilencer")) && flReloadTime <= GetGameTime())
{
// Call event
_call.ReloadFinish(client, weapon);
}
else
{
// Button reload press
if (iButtons & IN_RELOAD)
{
// Call event
_call.Reload(client, weapon);
iButtons &= (~IN_RELOAD); //! Bugfix
return Plugin_Changed;
}
}
// Button primary attack press
if (iButtons & IN_ATTACK)
{
// Call event
_call.PrimaryAttack(client, weapon);
iButtons &= (~IN_ATTACK); //! Bugfix
return Plugin_Changed;
}
// Button primary attack release
else if (iLastButtons & IN_ATTACK)
{
// Call event
_call.EndAttack(client, weapon);
}
// Call event
_call.Idle(client, weapon);
}
// Allow button
return Plugin_Continue;
}
/**
* @brief Trace filter.
*
* @param entity The entity index.
* @param contentsMask The contents mask.
* @param filter The filter index.
*
* @return True or false.
**/
public bool SelfFilter(int entity, int contentsMask, int filter)
{
return (entity != filter);
}